Manual del Usuario

Tabla de Contenido:

Introducción a Rockerfer Basic: ¡Una cordial bienvenida!

Conoce el Lenguaje

Referencia Completa

¡Una cordial bienvenida!

Rockerfer Basic es el lenguaje de programación ideal para un aprendizaje efectivo de técnicas básicas y avanzadas de programación. Sus características lo convierten en una útil herramienta para estudiantes que comienzan sus estudios de programación (ya sean básicos o superiores), y para aquellos en cursos avanzados, donde el diseño de algoritmos eficientes es clave para montar las bases sólidas de un proyecto a gran escala.

  • ¡El juego de instrucciones de Rockerfer Basic está en español!

  • Rockerfer Basic posee una sintaxis flexible, que permite escribir una instrucción de más de una manera.

  • Con Rockerfer Basic tú puedes ejecutar directamente tus programas o algoritmos escritos en pseudocódigo.

 

 

Conoce el Lenguaje

Primer programa

Directamente desde la página principal de Rockerfer Basic, podrás comenzar a escribir tu primer programa.

Dentro de la ventana, escribe la siguiente línea:

imprimir "Hola, mundo"

Ejecuta este programa haciendo click en "¡Ejecutar!". La línea "Hola Mundo" se mostrará cuando la página recargue. Eso significa que el programa se ejecutó correctamente.

La instrucción imprimir permite que tus programas muestren información por la pantalla de la computadora. Si utilizas varias instrucciones imprimir, una seguida de otra, notarás que las líneas que imprimen se mostrarán una debajo de la otra. Por ejemplo:

imprimir "Uno"
imprimir "Dos"

Mostrará:

Uno
Dos

Sin embargo, si la sentencia es finalizada con una coma (,), la siguiente sentencia imprimir imprimirá en la misma línea que su predecesora.

imprimir "Uno",
imprimir "Dos"

Mostrará:

UnoDos

Puedes separar varios elementos a imprimir usando comas:

imprimir "Uno","Dos","Tres"

»

UnoDosTres

Sinónimos

En Rockerfer Basic algunas instrucciones tienen sinónimos, es decir, que pueden escribirse de otras maneras. Así, imprimir puede escribirse como imprime, decir, (nótese el acento), escribir, escribe y con el símbolo '?'. En el siguiente ejemplo, todas las sentencias hacen exáctamente lo mismo:

imprimir "Tres"
imprime "Tres"
dí "Tres"
? "Tres"

»

Tres
Tres
Tres
Tres

¿Cuál utilizar? La que te plazca. ¡Ésa es la idea! De esa manera podrás diseñar tus programas cómodamente, sin tener que estar pendiente de cómo se escribe una instrucción. La mayoría de las instrucciones tienen sinónimos.

Variables y Datos

Rockerfer Basic posee tres tipos de datos: Entero, flotante y de cadena. El tipo de datos entero representa cualquier número real entero (sin decimales), positivo o negativo. El tipo flotante acepta cualquier número real (con decimales. Se puede utilizar la notación científica). El tipo cadena representa cualquier serie de caracteres alfanuméricos.

Tipo entero
Tipo flotante
Tipo cadena
45,-6,0
3.1415,-6E15
"Hola","a"

Los datos en Rockerfer Basic se pueden manipular literalmente, o almacenados en variables. La manipulación literal se refiere a la utilización directa del dato dentro de una sentencia. A continuación, ejemplos de manipulación literal dentro de la sentencia imprimir:

imprime 3
imprime "hola"+" chao"
imprime seno(2*3.1415926)

Las variables son áreas individuales de almacenamiento de datos con un nombre de identificación asociado. Las variables pueden almacenar datos de los tipos permitidos en Rockerfer Basic, es decir, que existen variables que almacenan datos enteros (llamadas variables de enteros), variables que almacenan datos flotantes (variables flotantes) o variables que almacenan datos de cadena (variables de cadena). A las variables enteras o flotantes se les suele llamar variables numéricas. A las variables de cadena pueden llamárseles variables alfanuméricas.

Las variables pueden ser identificadas con un nombre. A continuación, ejemplos de nombres de variables:

C,Edad,Puesto1,Porcentaje_Pagos,NOMBRE,tamaño,SeLeCcIóN

Rockerfer Basic permite el uso de acentos y la letra eñe en nombres de variables.

Las variables sólo pueden almacenar datos del tipo que se les asignó. Por ejemplo, si una variable almacena datos alfanuméricos (cadenas), no puede almacenar datos numéricos.

Para declarar una variable, dispones de dos maneras. La primera es utilizando la instrucción declarar:

declarar variable de cadena MiCadena
declarar variable entera UnEntero
declarar variable flotante PESOS

Si se omite el tipo, declarar asumirá el tipo entero.

Arreglos

Además de los tipos de variables ya mencionado, existe otro tipo de variable: las matrices o arreglos.

Los arreglos son colecciones de datos almacenados en variables del mismo tipo y con el mismo nombre. ¿Cómo identificar un dato en particular, si todas las variables de la colección tienen el mismo nombre? Cada variable tiene un atributo numérico llamado índice. El índice es único para cada dato, por lo tanto, podemos referirnos a una variable que forma parte del arreglo mediante su nombre y su índice. A continuación se presenta un arreglo de 5 enteros:

Arreglo de 5 enteros: 4,8,-3,0,1

Si suponemos que el arreglo usa el nombre "Valores" para ser identificado, entonces se puede hacer referencia a un valor en particular escribiendo el nombre de la variable junto con su índice escrito entre paréntesis:

Valores(1) = 4
Valores(2) = 8
Valores(3) = -3
Valores(4) = 0
Valores(5) = 1

En el ejemplo anterior, se puede observar que los índices de los arreglos son consecutivos, y se cuentan a partir del 1. Por ejemplo, si se tiene un arreglo de 25 cadenas, sus índices van del 1 al 25.

Los arreglos pueden utilizarse en cualquier contexto donde puede utilizarse una variable. A continuación, varios ejemplos donde se usan variables de arreglo:

declara variable de arreglos entera C(8)
sea C(4) igual a 20
sea C(2) igual a 30
imprime C(2)+C(4)

»

La sentencia imprimir imprimirá '50'.

declara variable de arreglos empleados(200)
sea B igual a 10
imprime empleados(20+B)


»


La sentencia imprimir imprimirá el contenido de la variable
'empleados(20+B)', es decir, el contenido de
'empleados(30)'

Como puede verse, para delcarar arreglos hay que agregar de arreglos y el índice entre paréntesis en la sentencia de declaración.

Asignación de datos a variables

¿Cuál es la segunda forma de declarar variables? Antes, vamos a ver cómo se asignan valores a las variables. De hecho, en el ejemplo anterior se vislumbra la forma en que ésto se hace. Para asignarle un valor a una variable, se utiliza la sentencia sea/igual a. El siguiente ejemplo, asignará "Hola" a la variable de cadena Saludos.

sea Saludos igual a "Hola"
imprime Saludos

»

La sentencia imprimir imprimirá 'Hola'.

A las variables pueden asignársele valores tantas veces como el usuario lo requiera. Los valores sólo pueden ser del mismo tipo de la variable. Si se intenta asignar una cadena a una variable flotante, Rockerfer Basic emitirá un error. La excepción es cuando se asigna un valor entero a una variable flotante. En este caso, sí funcionará, aunque el valor se convertirá implícitamente al tipo flotante. El caso inverso, asignar un valor flotante a una variable entera también funcionará, pero si el valor flotante contiene decimales, éstos serán eliminados.

declara variable de cadena MiCadena  
sea MiCadena igual a 90 Error
sea MiCadena igual a "Saludos" Válido
declara variable de cadena MiCadena  
declara variable flotante Peso  
sea Peso igual a 45 Válido
declara variable entera Edad  
sea Edad igual a 20.3 Válido, pero Edad vale 20.

En vez de sea/igual a pueden utilizarse: es igual a y el símbolo '=' (también conocido como operador de asignación):

sea Color igual a "Negro"
Color es igual a "Negro"
Color = "Negro"

He aquí el segundo método de declaración en Rockerfer Basic: Si se asigna un valor a una variable que no ha sido declarada previamente, la variable es creada automáticamente y con el tipo del valor que se le está asignando:

declarar variable de cadena Modelo
Modelo es igual a "Ferrari"
fin
 
Modela es igual a "Ferrari"
fin
Este programa y el anterior son equivalentes: Se declara una variable de cadena Modelo, y se le asigna la cadena "Ferrari".
Tamaño = 40 Creación implícita de la variable de enteros Tamaño y su correspondiente asignación.
Peso = 50.45 Creación implícita de la variable flotante Peso y su correspondiente asignación.
Tiempo = 30.0 Creación implícita de la variable flotante Tiempo y su correspondiente asignación.
Rasgos = "ninguno"
Rasgos = 40
La segunda sentencia generará un error, ya que Rasgos fue declarada implícitamente como de cadena.

Los arreglos siempre deben ser declarados antes de asignarles valores.

Estructuras de Programación

Rockerfer Basic cuenta con un juego de sentencias que permiten crear estructuras de programación, donde el flujo del programa cambia de acuerdo a una serie de condiciones. Estas estructuras se estudian en todo curso de iniciación a la programación. Aquí se discutirán las más comunes. Para una referencia completa, consulta la Referencia Completa.

Estructura para / hasta / fin para

Esta estructura permite ejecutar una sección del programa, tantas veces como se especifique. Por ejemplo, la siguiente sentencia:

imprimir "Hola"

Imprimirá "Hola" 1 sola vez. Si se requiere imprimir "Hola" 100 veces, existen varias alternativas. La primera es mandar a ejecutar el programa 100 veces. La segunda es escribir un programa con 100 sentencias para imprimir "Hola". Obviamente, ambas alternativas son en extremo ineficientes. La tercera es utilizando una estructura para / hasta / fin para:

sea Cuenta igual a 1
para Cuenta de 1 hasta 100 hacer
imprimir "Hola"
fin para

Si se ejecuta el programa anterior, se logrará el objetivo de imprimir "Hola" 100 veces. La estructura para / hasta / fin para cuenta con diversas opciones de uso. Consulta la Referencia Completa para más información.

Estructura si / entonces / fin si

Esta estructura es una de las más importantes, ya que permite que el programa decida si debe ejecutar una sección (o bloque) del programa, de acuerdo al cumplimiento de una condición. Vea el siguiente ejemplo:

sea Edad igual a 15
si Edad < 18, entonces
imprimir "En Venezuela, usted es menor de edad"
fin si
[...otras instrucciones...]

Cuando Rockerfer Basic alcanza la segunda línea de este programa, comprobará la condición de la estructura (en este caso, comprobará si el valor de la variable Edad es menor que 18). De resultar verdadera la condición, ejecutará el código que se encuentra a partir de la tercera línea (en este caso, sí lo hará, ya que la condición sí se cumplo, es decir, Edad que vale 15, es menor que 18). Si por ejemplo, Edad valiera 25, la condición ya no se cumple, e Rockerfer Basic no ejecutará la tercera línea. En vez de ello, continuará la ejecución del programa a partir de fin si.

Estructura repetir / hasta que

Esta estructura permite ejecutar un bloque de programa varias veces, hasta que cierta condición sea evaluada como verdadera. Por ejemplo:

repetir
imprimir "Introduzca la contraseña:"
leer Contraseña
hasta que Contraseña = "secreto"
imprimir "La contraseña es correcta"
[...otras instrucciones...]

El programa anterior pedirá una contraseña al usuario. Supongamos que el usuario suministra una contraseña diferente a la cadena "secreto". Cuando Rockerfer Basic alcanza la cuarta línea, verificará si la condición se cumple (es decir, si Contraseña es igual a "secreto"). Como no se cumple, entonces ejecutará nuevamente las sentencias a partir de la línea después de repetir. En el momento en que el usuario suministre la palabra "secreto" como contraseña, Rockerfer Basic alcance nuevamente la sentencia hasta que, continuará con las siguientes instrucciones, ya que la condición (Contraseña = "secreto") sí se cumple.

Las estructuras, aquí superficialmente discutidas, tienen más opciones que permiten escribir programas con gran flexibilidad. Aparte de estas estructuras, existen otras que permiten ejecutar ciertas tareas mucho más fácilmente. Si desea aprender más, revise la Referencia Completa.

Funciones Incorporadas

Rockerfer Basic cuenta con un juego de funciones que realizan tareas comunes de programación. Cada función posee su propio nombre (éste está relacionado con las tareas que dicha función realiza), y trabajan sobre datos provistos por el usuario (estos datos se conocen como parámetros).

Por ejemplo, si se quieren imprimir los primeros n caracteres de una cadena, se utiliza la función derecha():

sea Nombre igual a "Alejandra"
imprimir derecha(Nombre,3)

El programa anterior imprimirá "Ale".

derecha() tiene su contraparte, izquierda(). Por ejemplo:

imprimir izquierda("Saludos",2)

El programa anterior imprimirá "os".

Las funciones pueden utilizarse en cualquier expresión que requiera de un valor:

sea Palabra1 igual a "¿Qué día es hoy?"
sea Palabra2 igual a "¿Quién eres tú?"
sea Expresión igual a derecha(Palabra1,4)+izquierda(Palabra2,3)
imprimir Expresión

El programa anterior imprimirá la cadena "¿Quétú?".

Las funciones no sólamente devuelven valores alfanuméricos. Como ejemplo, la función longitud() devolverá el número de caracteres que contiene una cadena: longitud("hola") devuelve 4. coseno() devolverá el coseno de un número. abs() devolverá el valor absoluto de un número.

Para una lista completa de las funciones disponibles en Rockerfer Basic, consulta la sección Lista de las Funciones Incorporadas de Rockerfer Basic.

Ir a la tabla de contenido

 

 

Referencia Completa

El lenguaje Rockerfer Basic está especialmente diseñado para el aprendizaje de conceptos vistos en las etapas iniciales de los cursos de programación. Está basado en el lenguaje de pseudocódigo, lo cual significa que su juego de instrucciones representa una generalización de los juegos de instrucciones de otros lenguajes.

Estructura de un programa en Rockerfer Basic
Tipos de Datos
Variables
. -
Matrices (o arreglos)
Instrucciones
Lista de Instrucciones (orden alfabético)
Lista de Funciones (orden alfabético)
Referencia rápida de sinónimos

Estructura de un programa en Rockerfer Basic

Las declaraciones de variables y datos pueden aparecer en cualquier parte del programa, pero es común colocarlos en el principio del mismo.

Estructura típica de un programa en Rockerfer Basic:

Las declaraciones de variables y datos pueden hacerse en cualquier lugar del programa, aunque es recomendable que todas estén en el principio. De esta manera están más accesibles en momentos de depuración y modificación.

<declaraciones de variables y datos>
.
<instrucciones de programa>

Tipos de datos

Rockerfer Basic posee tres tipos de datos:

  • Entero: Representa cantidades numéricas, no decimales, cuyo rango está fijado entre -65536 y 65535.

  • Flotante: Representa cualquier cantidad numérica real, cuyo rango está fijado entre -10x10^100 hasta 10x10^100.

  • Cadenas: Representa series de caracteres (letras, símbolos y números) disponibles en el juego de caracteres del computador. Pueden almacenar cadenas de hasta 255 caracteres de longitud.

Los datos en Rockerfer Basic pueden representarse mediante cualquiera de estos tres tipos de datos, y pueden almacenarse en variables (véase a continuación) o ser utilizados directamente en instrucciones, tales como "imprimir".

Variables

Las variables son espacios de almacenamiento de datos con nombre. Se les puede hacer referencia usando su nombre. Los nombres de variables pueden ser de cualquier longitud hasta 64 caracteres, y pueden utilizarse letras, números, y el símbolo del subrayado "_", aunque no está permitido que el nombre comience con un número o el símbolo del subrayado. Rockerfer Basic no distingue las mayúsculas de las minúsculas en los nombres de variables por lo que, a manera de ejemplo, los tres nombres de variables "EDAD", "edad" y "Edad" representan todos a la misma variable.

Rockerfer Basic tampoco permite el uso de nombres de variables que coincidan con nombres de instrucciones o funciones. Por ejemplo, el nombre de variable "imprimir" no está permitido, ya que imprimir es una instrucción.

Ejemplos de nombres válidos:

cuenta

Nombre_Alumno

USUARIO21

p1

Ejemplos de nombres no válidos:

_usuario21

4estudiante

para (es una instrucción de Rockerfer Basic)

Rockerfer Basic posee un tipo de variable por cada tipo de dato, más las variables matrices (véase más adelante). Es decir, que están disponibles las variables de tipo entero, las de tipo flotante y las de tipo cadena.

Para asignar valores a las variables, se utiliza la siguiente sentencia:

Sea <nombre> igual a <valor>

Donde <nombre> es un nombre de variable, y <valor> es el valor a asignársele.

Ejemplo:

Sea X igual a 1

Esto asignará 1 a la variable X.

Las siguientes dos sentencias también realizan la misma función de asignar 1 a la variable X:

X es igual a 1
X = 1

Es de preferencia del usuario escoger qué sentencias utilizar.

Matrices (o arreglos)

Las matrices son colecciones de variables del mismo tipo, a las cuales pueden referirse utilizando un índice numérico. Por ejemplo, si tenemos una colección de cadenas:

"uno", "dos", "tres", "cuatro", "cinco",

éstas pueden almacenarse en una matriz. Llamemos "numeros" a esa matriz, y asignémosle las cadenas.

numeros(1) = "uno"
numeros(2) = "dos"
numeros(3) = "tres"
numeros(4) = "cuatro"
numeros(5) = "cinco"

Podemos referirnos a cualquiera de esos elementos utilizando el número de índice, que es el número ubicado entre paréntesis. Por ejemplo, las siguientes dos sentencias:

Sea I igual a 2
Imprime numeros(I)

Hará que Rockerfer Basic imprima "dos" en la ventana de salida.

La forma de declarar matrices en Rockerfer Basic, es usando la sintaxis siguiente:

Declarar variable <tipo> [de arreglos] <nombre_de_variable>(<indice>)

Como ejemplo, para declarar una matriz B de 10 elementos enteros, utilizamos:

Declarar variable de enteros B(10)

Otra alternativa:

Declara variable entera de arreglos B(10)

Si no se coloca el tipo, Rockerfer Basic asume el tipo entero.

Declara variable B(10)

La sentencia anterior declara una matríz B de 10 elementos que van desde B(1) hasta B(10).

Instrucciones en Rockerfer Basic

Rockerfer Basic cuenta con un rico juego de instrucciones, todas en español, que permiten realizar las más diversas tareas relacionadas con el mundo de la programación: entrada, salida y manipulación de datos, cálculos numéricos, iteraciones, bloques de decisión y bucles. Las instrucciones pueden escribirse sin tomar en cuenta las mayúsculas y minúsculas, por lo que 'Imprimir' se puede escribir 'IMPRIMIR', 'imprimir' o incluso 'iMpRiMiR'.

Una característica esencial del lenguaje Rockerfer Basic es su sintaxis flexible. Muchas de sus instrucciones pueden escribirse de más de una forma, de tal manera que el usuario no tenga que amoldarse a un solo estilo, pudiendo poner su atención en la búsqueda de la solución de sus ejercicios. Por ejemplo, la sentencia de asignación:

Edad = 0

Puede escribirse como:

Sea Edad igual a 0

O incluso:

Edad es igual a 0

Otro ejemplo, es la sentencia "imprimir", la cual puede escribirse como "imprime", "escribe", "escribir", o incluso "decir" o "dí".

Para más información, revisa la sección siguiente, "Lista de instrucciones de Rockerfer Basic".

Lista de instrucciones y sentencias de Rockerfer Basic (orden alfabético)

Esta lista contiene la descripción de cada una de las instrucciones del lenguaje Rockerfer Basic. Si encuentra el vocabulario empleado un tanto complicado, asesórate con tu tutor, o
contáctanos.

Las palabras encerradas entre paréntesis representan alternativas a la sintaxis original.

casos para/caso/fin para

Sintaxis:

casos [para] <variable>
caso <expresion1>
<sentencias1>
... caso <expresionN>
<sentenciasN>
caso [por] omisión
<sentenciasO>
fin casos

Rockerfer Basic evaluará cada una de las expresiones hasta que una de ellas concuerde con el valor de <variable>. Al encontrar un valor coincidente, Rockerfer Basic ejecutará las sentencias correspondientes a ese caso. Si hay dos o más valores iguales, Rockerfer Basic ejecutará sólo las sentencias del primer valor. Si no consigue ningún valor, el intérprete ejecutará <sentenciasO>, de
existir.

Ejemplo
:

sea r igual a 3
casos para r
caso 1
imprime "Es uno"
caso 2
imprime "Es dos"
caso 3
imprime "Es tres"
caso por omisión
imprime "No es ni 1, ni 2 ni 3"
fin casos

Símbolo del comentario ('#')

Sintaxis:

# <comentario>

Especifica que el resto de la línea es un comentario de programa y que el intérprete deberá ignorar. De esa manera, el intérprete continuará con la siguiente línea de programa. 'comentario' es útil para colocar observaciones, comentarios, explicaciones y anotaciones dentro del código del programa.

Ejemplo
:

# La siguiente sentencia imprime "Hola"
imprime "Hola"

declarar variable (declara, crear, crea)

Sintaxis:

declarar [la] variable ([[de]arreglo]|[matriz])|([[de]enteros]|[entera])|[flotante]|[[de]cadena] <variable>['('indice')']

Esta sentencia es utilizada para crear variables del tipo especificado. Si el tipo no se especifica, se asume el tipo entero.

Ejemplo
:

declarar variable de enteros C(10)

fin (final, terminar, finalizar)

Utilizado para denotar el final del programa. Todo lo que venga después no será tomado en cuenta. Si se omite, el intérprete asumirá el final del programa como el final del archivo.

Ejemplo
:

imprime "Este programa finalizará pronto"
fin

imprimir (imprime, dí, decir, escribe, escribir, '?')

Sintaxis:

Imprimir <expresión1>,
<expresión2>,...
[,]

Se utiliza para mandar información a la salida en pantalla del usuario.
Si al final de la sentencia se agrega una coma, el cursor no pasará a una nueva línea, sino que se quedará en la misma línea esperando por otra sentencia a imprimir. Pero si se omite esa coma al final, la próxima sentencia imprimir imprimirá en la siguiente línea.

Ejemplo
:

Sumando1 es igual a 45
Sumando2 es igual a 55
imprime "El resultado de sumar ",
imprime Sumando1," y ",Sumando2," da: ",
imprime Sumando1+Sumando2
imprime "Es todo"

leer (lee, entrar, entra)

Sintaxis:

lee <var1>,<var2>,<var3>,...

Se utiliza para asignar valores entrados por teclado a las variables especificadas. Rockerfer Basic esperará a que el usuario presione la tecla ENTER para asignar un valor a una variable, y después esperará por la siguiente variable.

Ejemplo
:

dí "Escribe tu nombre: ",
lee Nombre
dí "¡Hola, ",Nombre,"!"

mientras / hacer / fin mientras

Sintaxis:

mientras <expresión> hacer
<sentencias>
fin mientras

Rockerfer Basic evaluará <expresión> y a continuación ejecutará <sentencias1>. Esto lo hará repetidas veces hasta que <expresión> se evalúe como verdadera. Si <expresión> es falsa en la primera evaluación, <sentencias1> nunca se ejecutará.

Ejemplo
:

sea Nombre igual a ""
mientras Nombre = "" hacer
dí "Escribe tu nombre:"
fin mientras
imprime "Hola, ",Nombre

para / hasta / fin para

Sintaxis:

para <variable>
de <expresión1>
hasta <expresión2>
[pasos [de] <expresion2>]
[,] hacer

<sentencias1>

fin para

Rockerfer Basic inicializará <variable> con <expresión1>, e incrementará su valor hasta que sea igual o supere a <expresión2>. Por cada incremento, ejecutará las sentencias encerradas entre 'hacer' y 'fin'.<variable> será incrementada en una unidad, a menos de que se especifique el incremento con 'pasos'. Si <expresión1> sobrepasa en la primera pasada a <expresión2>, el código no se ejecuta. <variable> puede utilizarse dentro del ciclo. Adviértase que <variable> no puede ser parte de un arreglo.

Ejemplo
:

para E de 1 hasta 20 hacer
imprime "E vale: ",E
fin para

repetir / hasta (repite/hasta)

Sintaxis:

repetir <sentencias1>
hasta que <expresion1>
fin repetir

El intérprete ejecutará <sentencias1> y a continuación evaluará <expresión1>. De resultar falsa, el intérprete vuelve al principio de <sentencias1> y repite el mismo proceso. <sentencias1> se ejecutará al menos una vez.

Ejemplo
:

sea Suma igual a 0
declarar variable entera Entrada
repetir
imprime "Introduce un número"
lee Entrada
Suma=Suma+Entrada
hasta que Suma>100
imprime "La suma de todas las entradas sobrepasa a 100"

sea / igual a ('=', es igual a)

Sintaxis:

sea <variable> igual a <expresión>

'sea/igual a' es un operador de asignación de variables. Puede ser utilizado para crear e inicializar variables (pero no se pueden crear arreglos). Si se especifica un índice, entonces se crea un arreglo (o matriz) de tantas variables como lo especifique dicho índice.

Ejemplo
:

sea TipoCasa igual a "mansión"
sea Dueño igual a "Pedro"
imprime Dueño," tiene una ",TipoCasa

si / entonces / fin si

Sintaxis:

si <expresion>
([,]entonces|,[entonces])
<sentencias1>
[[en] caso contrario|sino]
<sentencias2>
fin si

El intérprete evaluará <expresion>, y de resultar verdadera, ejecutará <sentencias1>. Si resulta falsa entonces, de existir, ejecutará <sentencias2>. Si no se especifica <sentencias2>, sencillamente pasará a ejecutar la siguiente sentencia.

Ejemplo
:

decir "Dime tu nombre:"
lee Nombre
si Nombre es igual a "José", entonces
decir "¡Hola! ¡Yo te conozco!"
en caso contrario
decir "No te conozco"
fin si

terminar (finalizar)

Sintaxis:

(terminar|finalizar) [programa]

Este comando le indica a Rockerfer Basic que termine con la ejecución del programa. Rockerfer Basic dejará de ejecutar instrucciones una vez que encuentre una instrucción terminar.

Lista de las funciones incorporadas de Rockerfer Basic (orden alfabético)

Estas funciones pueden ser utilizadas en cualquier expresión válida de Rockerfer Basic.

abs(n)

n puede ser un valor numérico cualquiera (flotante o entero).

Devuelve el valor absoluto de n.

Ejemplo: abs(-3) devuelve 3.

aleatorio()

Devuelve un número flotante aleatorio mayor o igual que 0 y menor que 1.

Ejemplo: aleatorio() devuelve 0.23452347

cadena(n)

n puede ser un valor numérico cualquiera (flotante o entero).

Devuelve n como una cadena alfanumérica.

Ejemplo: cadena(34) devuelve "34" (como cadena).

coseno(n)

n puede ser un valor numérico cualquiera (flotante o entero), representando un valor en radianes.

Devuelve el coseno de n, donde n es un ángulo en radianes..

Ejemplo: coseno(0) devuelve 1.

derecha(s,n)

s es una cadena. n es un entero.

Devolverá los n caracteres por la derecha de s.

Ejemplo: derecha("Hola",2) devuelve "la".

entero(n)

n puede ser un valor numérico cualquiera (flotante o entero).

Devuelve la parte entera de n.

Ejemplo: entero(67.89) devuelve 67.

exp(n)

n puede ser un valor numérico cualquiera (flotante o entero).

Devuelve el valor exponencial de n.

Ejemplo: exp(1) devuelve 2.71828182845905 (e).

izquierda(s,n)

s es una cadena. n es un entero.

Devolverá los n caracteres por la izquierda de s.

Ejemplo: izquierda("Hola",2) devuelve "Ho".

log10(n)

n puede ser un valor numérico cualquiera (flotante o entero).

Devolverá el logaritmo en base 10 de n.

Ejemplo: log10(10) devuelve 1.

logn(n)

n puede ser un valor numérico cualquiera (flotante o entero).

Devolverá el logaritmo natural (o neperiano) de n.

Ejemplo: logn(1) devuelve 0.

longitud(s)

s es una cadena.

Devolverá el número de caracteres contenidos en s (recuerde que los espacios en blanco cuentan como caracteres).

Ejemplo: longitud("Hola") devuelve 4.

raizc(n)

n puede ser un valor numérico cualquiera (flotante o entero).

Devuelve la raíz cuadrada de n.

Ejemplo: raizc(9) devuelve 3.

seno(n)

n puede ser un valor numérico cualquiera (flotante o entero).

Devuelve el seno de n, donde n es un ángulo en radianes.

Ejemplo: seno(0) devuelve 0.

signo(n)

n puede ser un valor numérico cualquiera (flotante o entero).

Devolverá 1 si n es mayor que 0, 0 si n es 0, y -1 si n es menor que 0.

Ejemplo: signo(-15) devuelve -1.

subcadena(s,n,m)

s es una cadena. n y m son valores enteros.

Devolverá los m caracteres consecutivos de s, partiendo desde n. Si m es omitido, devolverá todos los caracteres de s partiendo desde n.

Ejemplo: subcadena("Hola",2,2) devuelve "ol".
subcadena("Matemáticas",3) devuelve "temáticas".

tangente(n)

n puede ser un valor numérico cualquiera (flotante o entero).

Devuelve la tangente de n, donde n es un ángulo en radianes.

Ejemplo: tangente(0) devuelve 0.

valor(s)

s es una cadena.

Devuelve el equivalente numérico de s.

Ejemplo: valor("34.5") devuelve 34.5.

Referencia rápida de sinónimos

Nombre de la instrucción Sinónimo(s)
declarar (variable)
declara, crear, crea (variable)
fin
final, terminar, finalizar
imprimir
imprime, dí, decir, escribe, escribir, '?'
leer
lee, entrar, entra
repetir
repite
sea/igual a
'=', es igual a
en caso contrario
sino
terminar
finalizar

Ir a la tabla de contenido


© 2005 Rafael Pacheco. Reservados todos los Derechos.


Volver a la Página Principal